Fichier:Lagrangian points equipotential.gif
Aller à la navigation
Aller à la recherche
Pas de plus haute résolution disponible.
Lagrangian_points_equipotential.gif (512 × 384 pixels, taille du fichier : 2 Mio, type MIME : image/gif, en boucle, 72 trames, 7,2 s)
Remarque : en raison de limitations techniques, les vignettes des images GIF en haute résolution telles que celle-ci ne seront pas animées.
Description
| Description |
English: Animation showing the relationship between the five Lagrangian points (red) of a planet (blue) orbiting a star (yellow), and the gravitational potential in the plane containing the orbit (grey surface with purple contours of equal potential). The potential was computed in POV-Ray using
for q = 0.1 and z = 0.[1] |
| Source | Travail personnel |
| Auteur | cmglee |
| Autres versions |
|
| GIF information |
POV-Ray source code
| Lagrangian_points_equipotential.pov | Lagrangian_points_equipotential.ini |
|---|---|
#declare rotation = clock;
// #declare rotation = -28;
#declare bounding_radius = 8;
#declare q = 0.1;
#declare q_plus_1 = q + 1;
#declare q_divide_q_plus_1 = q / q_plus_1;
#declare two_divide_q_plus_1 = 2 / q_plus_1;
union {
isosurface {
function {
y + (pow(x-q_divide_q_plus_1,2) + z*z + two_divide_q_plus_1 * (q / sqrt((x-1)*(x-1)+z*z) + 1 / sqrt(x*x + z*z)))
}
accuracy 0.001
max_gradient 200 // increase to reduce artifact in funnel
contained_by {sphere{0,bounding_radius}} open
pigment {
gradient <0,1,0>
color_map { [0.01 color rgb <0.5,0,0.75>][0.02 color rgb 1]
[0.18 color rgb 1][0.19 color rgb <0.75,0.5,1>][0.21 color rgb <0.75,0.5,1>][0.22 color rgb 1]
[0.38 color rgb 1][0.39 color rgb <0.75,0.5,1>][0.41 color rgb <0.75,0.5,1>][0.42 color rgb 1]
[0.58 color rgb 1][0.59 color rgb <0.75,0.5,1>][0.61 color rgb <0.75,0.5,1>][0.62 color rgb 1]
[0.78 color rgb 1][0.79 color rgb <0.75,0.5,1>][0.81 color rgb <0.75,0.5,1>][0.82 color rgb 1]
[0.98 color rgb 1][0.99 color rgb <0.75,0.5,1>] }
scale 0.5
translate <0,0.03,0>
}
scale <1,0.5,1>
translate <0,1.42,0>
}
union {
sphere {0,0.2 pigment {rgbt <1,1,0,0.5>} interior {ior 1} finish {specular 1 roughness 0.1} }
sphere {<1,0,0>,0.1 pigment {rgbt <0,0.5,1,0.5>} interior {ior 1} finish {specular 1 roughness 0.1} }
sphere {<q/2,0,0>,0.05 pigment {rgb <0.5,0,0>} }
union {
torus {1-q/2,0.02 translate <q/2,0,0>}
cylinder {<-0.95,0,0>,<1.35,0,0>,0.02}
cylinder {<q/2,0,0>,<0.5,0,0.866>,0.02}
cylinder {<q/2,0,0>,<0.5,0,-0.866>,0.02}
pigment {rgb <0,0.75,0>}
}
union {
union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L1" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.72,0,0> }
union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L2" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <1.35,0,0> }
union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L3" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <-0.95,0,0> }
union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L4" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.5,0,0.866> }
union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L5" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.5,0,-0.866> }
pigment {rgb <1,0,0>}
}
}
translate <-q/2,-0.14,0>
rotate <0,-rotation,0>
}
sky_sphere {pigment {rgb 1}}
light_source {<0,1,0> color rgb 0.5 parallel point_at 0}
light_source {<0,10,-10> color rgb 1 shadowless}
camera {orthographic location <0.05,7.8,-10> look_at <0.05,-0.1,0> angle 13.8}
|
Antialias=off
Antialias_Threshold=0.01
Antialias_Depth=2
Input_File_Name="Lagrangian_points_equipotential.pov"
Initial_Frame=0
Final_Frame=71
Initial_Clock=0
Final_Clock=360
Cyclic_Animation=on
Pause_when_Done=off
|
- ↑ Seidov, ZF (2004-03-01). "The Roche Problem: Some Analytics". The Astrophysical Journal (603): 283-284.
Conditions d’utilisation
Moi, en tant que détenteur des droits d’auteur sur cette œuvre, je la publie sous les licences suivantes :
Ce fichier est disponible selon les termes de la licence Creative Commons Attribution – Partage dans les Mêmes Conditions 3.0 Non Transposé.
- Vous êtes libre :
- de partager – de copier, distribuer et transmettre cette œuvre
- d’adapter – de modifier cette œuvre
- Sous les conditions suivantes :
- paternité – Vous devez donner les informations appropriées concernant l'auteur, fournir un lien vers la licence et indiquer si des modifications ont été faites. Vous pouvez faire cela par tout moyen raisonnable, mais en aucune façon suggérant que l’auteur vous soutient ou approuve l’utilisation que vous en faites.
- partage à l’identique – Si vous modifiez, transformez ou vous basez sur cet élément, vous devez distribuer votre contribution sous une license identique ou compatible à celle de l’original.
|
Vous avez la permission de copier, distribuer et modifier ce document selon les termes de la GNU Free Documentation License version 1.2 ou toute version ultérieure publiée par la Free Software Foundation, sans sections inaltérables, sans texte de première page de couverture et sans texte de dernière page de couverture. Un exemplaire de la licence est inclus dans la section intitulée GNU Free Documentation License. |
Vous pouvez choisir l’une de ces licences.
Historique du fichier
Cliquer sur une date et heure pour voir le fichier tel qu'il était à ce moment-là.
| Date et heure | Vignette | Dimensions | Utilisateur | Commentaire | |
|---|---|---|---|---|---|
| actuel | 23 octobre 2021 à 00:57 | | 512 × 384 (2 Mio) | wikimediacommons>Cmglee | Increase resolution and framerate, rotate around barycentre, reframe image and make bodies transparent |
Utilisation du fichier
Les 3 pages suivantes utilisent ce fichier :
