DescriptionLoi de mouvement sinmod en acceleration.svg	Français : Loi de mouvement sinusoïdal modifié en accélération (sin-mod). English: Modified sinusoidal (mod-sin) acceleration motion law.
Date	31 août 2018
Source	Travail personnel
Auteur	Cdang
SVG information InfoField	Le code de ce fichier SVG est valide.  Cette formule développée plane a été créée avec Batik par cdang   Ce fichier SVG utilise du texte encapsulé qui peut être traduit facilement à l'aide d'un éditeur de texte.

Équations :

1. t ∈ [0 ; T/8] ${\displaystyle {\begin{cases}x={\frac {\pi }{\pi +4}}x_{\mathrm {f} }\left[{\frac {t}{\mathrm {T} }}-{\frac {1}{4\pi }}\sin \left(4\pi {\frac {t}{\mathrm {T} }}\right)\right]\\v={\frac {\pi }{\pi +4}}{\frac {x_{\mathrm {f} }}{\mathrm {T} }}\left[1-\cos \left(4\pi {\frac {t}{\mathrm {T} }}\right)\right]\\a={\frac {4\pi ^{2}}{\pi +4}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{2}}}\sin \left(4\pi {\frac {t}{\mathrm {T} }}\right)\\j={\frac {16\pi ^{3}}{\pi +4}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{3}}}\cos \left(4\pi {\frac {t}{\mathrm {T} }}\right)\end{cases}}}$

2. t ∈ [T/8 ; 7T/8] ${\displaystyle {\begin{cases}x={\frac {\pi }{\pi +4}}x_{\mathrm {f} }\left[{\frac {t}{\mathrm {T} }}-{\frac {9}{4\pi }}\cos \left({\frac {4\pi }{3}}\left({\frac {t}{\mathrm {T} }}-{\frac {1}{8}}\right)\right)+{\frac {2}{\pi }}\right]\\v={\frac {\pi }{\pi +4}}{\frac {x_{\mathrm {f} }}{\mathrm {T} }}\left[1+3\sin \left({\frac {4\pi }{3}}\left({\frac {t}{\mathrm {T} }}-{\frac {1}{8}}\right)\right)\right]\\a={\frac {4\pi ^{2}}{\pi +4}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{2}}}\cos \left({\frac {4\pi }{3}}\left({\frac {t}{\mathrm {T} }}-{\frac {1}{8}}\right)\right)\\j={\frac {16\pi ^{3}}{3(\pi +4)}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{3}}}\sin \left({\frac {4\pi }{3}}\left({\frac {t}{\mathrm {T} }}-{\frac {1}{8}}\right)\right)\end{cases}}}$

3. t ∈ [7T/8 ; T] ${\displaystyle {\begin{cases}x={\frac {\pi }{\pi +4}}x_{\mathrm {f} }\left[{\frac {t}{\mathrm {T} }}-{\frac {1}{4\pi }}\sin \left(4\pi {\frac {t}{\mathrm {T} }}\right)+{\frac {4}{\pi }}\right]\\v={\frac {\pi }{\pi +4}}{\frac {x_{\mathrm {f} }}{\mathrm {T} }}\left[1-\cos \left(4\pi {\frac {t}{\mathrm {T} }}\right)\right]\\a={\frac {4\pi ^{2}}{\pi +4}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{2}}}\sin \left(4\pi {\frac {t}{\mathrm {T} }}\right)\\j={\frac {16\pi ^{3}}{\pi +4}}{\frac {x_{\mathrm {f} }}{\mathrm {T} ^{3}}}\cos \left(4\pi {\frac {t}{\mathrm {T} }}\right)\end{cases}}}$

Deutsch ∙ English ∙ +/−

function [t1, t2, t3] = indice(t)
    t1 = (t <= 1/8);
    t2 = (t > 1/8) & (t <= 7/8);
    t3 = (t>7/8);
endfunction

function [j]=jerk(t)
    [t1, t2, t3] = indice(t)
    j = zeros(t);
    coef = 4*%pi*%pi/(4 + %pi)
    j(t1) = coef*4*%pi*cos(4*%pi*t(t1));
    j(t2) = -coef*4/3*%pi*sin(4*%pi/3*(t(t2) - 1/8));
    j(t3) = coef*4*%pi*cos(4*%pi*t(t3));
    endfunction

function [a]=acceleration(t)
    [t1, t2, t3] = indice(t)
    a = zeros(t);
    coef = 4*%pi*%pi/(4 + %pi);
    a(t1) = coef*sin(4*%pi*t(t1));
    a(t2) = coef*cos(4*%pi/3*(t(t2) - 1/8));
    a(t3) = coef*sin(4*%pi*t(t3));
    endfunction

function [v] = vitesse(t)
    [t1, t2, t3] = indice(t)
    coef = %pi/(%pi + 4);
    v = zeros(t);
    v(t1) = coef*(1 - cos(4*%pi*t(t1)));
    v(t2) = coef*(1 + 3*sin(4*%pi/3*(t(t2) - 1/8)));
    v(t3) = coef*(1 - cos(4*%pi*t(t3)));
endfunction

function [x] = position(t)
    [t1, t2, t3] = indice(t)
    x = zeros(t);
    coef = %pi/(%pi + 4);
    x(t1) = coef*(t(t1) - 1/(4*%pi)*sin(4*%pi*t(t1)));
    x(t2) = coef*(t(t2) - 9/(4*%pi)*cos(4*%pi/3*(t(t2) - 1/8)) + 2/%pi);
    x(t3) = coef*(t(t3) - 1/(4*%pi)*sin(4*%pi*t(t3)) + 4/%pi);
endfunction

// tracé

t = 0:0.005:1;

j = jerk(t);
a = acceleration(t);
v = vitesse(t);
x = position(t);

scf(0);
clf;

subplot(4, 1, 1)
plot(t, x)
xtitle("position", "t/T", "$x/x_\mathrm{f}$")

subplot(4, 1, 2)
plot(t, v)
xtitle("vitesse", "t/T", "$v/(x_\mathrm{f}/\mathrm{T})$")

subplot(4, 1, 3)
plot(t, a)
xtitle("accélération", "t/T", "$a/(x_\mathrm{f}/\mathrm{T}^2)$")

subplot(4, 1, 4)
plot(t, j)
xtitle("à-coup", "t/T", "$j/(x_\mathrm{f}/\mathrm{T}^3)$")

Moi, en tant que détenteur des droits d’auteur sur cette œuvre, je la publie sous la licence suivante :

Ce fichier est sous la licence Creative Commons Attribution – Partage dans les Mêmes Conditions 4.0 International.

Vous êtes libre :

• de partager – de copier, distribuer et transmettre cette œuvre
• d’adapter – de modifier cette œuvre

Sous les conditions suivantes :

• paternité – Vous devez donner les informations appropriées concernant l'auteur, fournir un lien vers la licence et indiquer si des modifications ont été faites. Vous pouvez faire cela par tout moyen raisonnable, mais en aucune façon suggérant que l’auteur vous soutient ou approuve l’utilisation que vous en faites.
• partage à l’identique – Si vous modifiez, transformez ou vous basez sur cet élément, vous devez distribuer votre contribution sous une license identique ou compatible à celle de l’original.

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue